Aide LibreOffice 25.8
Cette catégorie contient les fonctions mathématiques de Calc. Pour ouvrir l'assistant Fonctions, choisissez Insertion - Fonction.
Cette fonction renvoie un résultat groupé des calculs de la plage. Vous pouvez utiliser différentes fonctions de groupement listées ci-dessous. La fonction AGREGAT vous permet d'omettre les lignes masquées, les erreurs, SOUS-TOTAUX et les autres résultats de fonction AGREGAT du calcul.
Ajoute un ensemble de nombres.
Renvoie la somme des valeurs des cellules d'une plage qui répond à des critères multiples dans plusieurs plages.
Renvoie la valeur absolue d'un nombre.
ABS(nombre)
nombre est le nombre dont la valeur absolue est à calculer. La valeur absolue d'un nombre est sa valeur sans le signe +/-.
=ABS(-56) renvoie 56.
=ABS(12) renvoie 12.
=ABS(0) renvoie 0.
Renvoie le cosinus trigonométrique inverse d'un nombre.
ACOS(nombre)
Cette fonction renvoie le cosinus trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont le cosinus est nombre. L'angle renvoyé est entre 0 et PI.
Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.
=ACOS(-1) renvoie 3,14159265358979 (PI radians)
=DEGRES(ACOS(0,5)) renvoie 60. Le cosinus de 60 degrés est 0,5.
Renvoie le cosinus hyperbolique inverse d'un nombre.
ACOSH(nombre)
La fonction renvoie le cosinus hyperbolique inverse de nombre, c'est à dire le nombre dont le cosinus hyperbolique est nombre.
Nombre doit être supérieur ou égal à 1.
=ACOSH(1) renvoie 0.
=ACOSH(COSH(4)) renvoie 4.
Renvoie la cotangente inverse (l'arc cotangente) d'un nombre donné.
ACOT(nombre)
Cette fonction renvoie la cotangente trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont la cotangente est nombre. L'angle renvoyé est entre 0 et PI.
Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.
=ACOT(1) renvoie 0,785398163397448 (PI/4 radians).
=DEGRES(ACOT(1)) renvoie 45. La tangente de 45 degrés est 1.
Renvoie la cotangente hyperbolique inverse du nombre donné.
ACOTH(nombre)
Cette fonction renvoie la cotangente hyperbolique inverse de nombre, c'est à dire le nombre dont la cotangente hyperbolique est nombre.
Il résulte une erreur si le nombre est compris entre -1 et 1 inclus.
=ACOTH(1,1) renvoie la cotangente hyperbolique inverse de 1,1, approximativement 1,52226.
Renvoie un nombre aléatoire compris entre 0 et 1.
ALEA()
Cette fonction produit un nouveau nombre aléatoire à chaque fois que Calc recalcule. Pour forcer Calc à recalculer manuellement, appuyez sur F9.
Pour générer des nombre aléatoires qui ne sont jamais recalculés, faites :
Copiez toutes les cellules contenant =ALEA(), et utilisez (avecTout coller et Formules non cochés et Nombres cochés).
Utilisez la commande Remplir les cellules avec des nombres aléatoires().
Utilisez la fonction ALEA.NV() pour les nombres aléatoires non volatiles.
=ALEA() renvoie un nombre entre 0 et 1.
Renvoie un nombre entier aléatoire compris dans une plage spécifiée.
ALEA.ENTRE.BORNES(minimum;maximum)
Renvoie un nombre entier aléatoire entre les nombres entiers minimum et maximum (tous deux inclusifs).
Cette fonction produit un nouveau nombre aléatoire à chaque fois que Calc recalcule. Pour forcer Calc à recalculer manuellement, appuyez sur F9.
Pour générer des nombres aléatoires qui ne sont jamais recalculés, copiez les cellules contenant cette fonction et utilisez (avec et non cochées et coché).
=ALEA.ENTRE.BORNES(20;30) renvoie un nombre entier entre 20 et 30.
Renvoie un nombre aléatoire entier non volatile dans une plage spécifiée.
ALEA.ENTRE.BORNES.NV(bas;haut)
Renvoie un nombre entier aléatoire non volatil entre les entiers Bas et Haut (tous deux inclus). Une fonction non volatile n'est pas recalculée lors de nouveaux événements d'entrée ou en appuyant sur F9. Cependant, la fonction est recalculée lors de l'appui sur F9 avec le curseur sur la cellule contenant la fonction, lors de l'ouverture du fichier, lors de l'utilisation de la commande (Maj+Commande Ctrl+F9) et quand Haut ou Bas sont recalculés.
=ALEA.ENTRE.BORNES.NV(20;30) renvoie un nombre entier non volatile entre 20 et 30.
=ALEA.ENTRE.BORNES.NV(A1;30) renvoie un nombre entier non volatile entre la valeur de la cellule A1 et 30. La fonction est recalculée lorsque le contenu de la cellule A1 est modifié.
ORG.LIBREOFFICE.RANDBETWEEN.NV
Renvoie un nombre aléatoire non volatile entre 0 et 1.
ALEA.NV()
Cette fonction produit un nombre aléatoire non volatile en entrée. Une fonction non volatile n'est pas recalculée lors de nouveaux événements d'entrée. La fonction ne recalcule pas en appuyant sur F9, sauf lorsque le curseur est sur la cellule contenant la fonction ou en utilisant la commande (Maj+Commande Ctrl+F9). La fonction est recalculée à l'ouverture du fichier.
=ALEA.NV() renvoie un nombre aléatoire non volatile entre 0 et 1.
ORG.LIBREOFFICE.RAND.NV
Arrondit un nombre à un nombre spécifique de décimales.
ARRONDI(nombre[;nombre])
Renvoie le nombre arrondi au nombre de décimales. Si le nombre est omis ou est zéro, la fonction arrondit au nombre entier le plus proche. Si le nombre est négatif, la fonction arrondit au plus proche de 10, 100, 1000, etc.
Cette fonction arrondit au nombre le plus proche. Voir ARRONDI.INF et ARRONDI.SUP pour des alternatives.
=ARRONDI(2,348;2) renvoie 2,35
=ARRONDI(-32,4834;3) renvoie -32,483. Modifiez le format de la cellule pour afficher toutes les décimales.
=ARRONDI(2,348;0) renvoie 2.
=ARRONDI(2,5) renvoie 3.
=ARRONDI(987,65;-2) renvoie 1 000.
Le résultat obtenu est le multiple entier le plus proche du nombre.
ARRONDI.AU.MULTIPLE(nombre;multiple)
Renvoie un nombre arrondit au multiple le plus proche de multiple.
Une implémentation alternative serait Multiple * ARRONDI(nombre/multiple).
=ARRONDI.AU.MULTIPLE(15,5;3) renvoie 15, car 15,5 est plus près de 15 (= 3*5) que de 18 (= 3*6).
=ARRONDI.AU.MULTIPLE(1,4;0,5) renvoie 1,5 (= 0,5*3).
Arrondit un nombre à la valeur immédiatement supérieure en fonction de la décimale spécifiée.
ARRONDI.SUP(nombre[;nombre])
Renvoie le nombre arrondi à la valeur supérieure (éloignée de zéro) au nombre de décimales. Si le nombre est omis ou est zéro, la fonction arrondit au nombre entier supérieur. Si le nombre est négatif, la fonction arrondit au supérieur au plus proche de 10, 100, 1 000, etc.
Cette fonction arrondit en s'éloignant de zéro. Voir ARRONDI.INF et ARRONDI pour des alternatives.
=ARRONDI.SUP(1,1111;2) renvoie 1,12.
=ARRONDI.SUP(1,2345;1) renvoie 1,3.
=ARRONDI.SUP(45,67;0) renvoie 46.
=ARRONDI.SUP(-45,67) renvoie -46.
=ARRONDI.SUP(987,65;-2) renvoie 1 000.
Renvoie le sinus trigonométrique inverse d'un nombre.
ASIN(nombre)
Cette fonction renvoie le sinus trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont le sinus est nombre. L'angle renvoyé est entre -PI/2 et + PI/2.
Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.
=ASIN(0) renvoie 0.
=ASIN(1) renvoie 1,5707963267949 (PI/2 radians).
=DEGRES(ASIN(0,5)) renvoie 30. Le sinus de 30 degrés est 0,5.
Renvoie le sinus hyperbolique inverse d'un nombre.
ASINH(nombre)
Cette fonction renvoie le sinus hyperbolique inverse de nombre, c'est à dire le nombre dont le sinus hyperbolique est nombre.
=ASINH(-90) renvoie approximativement -5,1929877.
=ASINH(SINH(4)) renvoie 4.
Renvoie la tangente trigonométrique inverse d'un nombre.
ATAN(nombre)
Cette fonction renvoie la tangente trigonométrique inverse de nombre, c'est à dire l'angle (en radians) dont la tangente est nombre. L'angle renvoyé est entre -PI/2 et PI/2.
Pour renvoyer un angle en degrés, utilisez la fonction DEGRES.
=ATAN(1) renvoie 0,785398163397448 (PI/4 radians).
=DEGRES(ATAN(1)) renvoie 45. La tangente de 45 degrés est 1.
Renvoie l'angle (en radians) entre l'axe x et une ligne de l'origine au point (NombreX|NombreY).
ATAN2(nombreX;nombreY)
nombreX est la valeur de la coordonnée x.
nombreY représente la valeur des coordonnées y.
Les langages de programmation ont habituellement l'ordre opposé des arguments pour leur fonction atan2().
ATAN2 renvoie l'angle (en radians) entre l'axe x et une ligne de l'origine au point (NombreX|NombreY).
=ATAN2(-5;9) renvoie 2,07789 radians.
Pour obtenir l'angle en degrés appliquez la fonction DEGRES au résultat.
=DEGRES(ATAN2(12,3;12,3)) renvoie 45. La tangente de 45 degrés est 1.
LibreOffice renvoie 0 pour ATAN2(0;0).
La fonction peut être utilisée pour convertir des coordonnées cartésiennes en coordonnées polaires.
=DEGRES(ATAN2(-8;5)) renvoie φ = 147,9 degrés
Renvoie la tangente hyperbolique inverse d'un nombre.
ATANH(nombre)
Cette fonction renvoie la tangente hyperbolique inverse de nombre, c'est à dire le nombre dont la tangente hyperbolique est nombre.
Le nombre doit obéir à la condition -1 < nombre < 1.
=ATANH(0) renvoie 0.
Renvoie le nombre de combinaisons pour des éléments sans répétition.
COMBIN(nombre1;nombre2)
nombre1 est le nombre d'éléments dans l'ensemble.
nombre2 est le nombre d'éléments à choisir dans l'ensemble.
COMBIN renvoie le nombre de façon ordonné de choisir ces éléments. Par exemple, s'il y a 3 éléments A, B et C dans un ensemble, vous pouvez choisir 2 éléments de 3 façons différentes : AB, AC et BC.
COMBIN implémente la formule : nombre1!/(nombre2!*(nombre1-nombre2)!)
=COMBIN(3;2) renvoie 3.
Renvoie le nombre de combinaisons pour un sous ensemble d'éléments incluant les répétitions.
COMBINA(nombre1;nombre2)
nombre1 est le nombre d'éléments dans l'ensemble.
nombre2 est le nombre d'éléments à choisir dans l'ensemble.
COMBINA renvoie le nombre de façons uniques de choisir ces éléments, où l'ordre du choix est sans importance et les répétions d'éléments sont autorisées. Par exemple, s'il y a 3 éléments A, B et C dans un ensemble, vous pouvez choisir 2 éléments de 6 façons différentes, nommément : AA, AB, AC, BB, BC et CC.
COMBINA implémente la formule : (nombre1+nombre2-1)!/(nombre2!(nombre1-1)!)
=COMBINA(3;2) renvoie 6.
Convertit en euros une valeur monétaire exprimée dans l'une des anciennes devises des 19 États membres de la zone euro, et vice versa. La conversion utilise les taux de change fixes auxquels les anciennes devises sont entrées l'euro.
Nous vous recommandons d'utiliser la fonction EUROCONVERT plus flexible pour la conversion entre ces devises. CONVERTIR_OOO n'est pas une fonction standardisée et n'est pas portable.
CONVERTIR_OOO(valeur;"texte1";"texte2")
valeur est le montant de la monnaie à convertir.
texte1 est une chaîne de trois caractères qui spécifie la devise à partir de laquelle convertir.
texte2 est une chaîne de trois caractères qui spécifie la devise à convertir.
texte1 et texte2 doivent chacun prendre l'une des valeurs suivantes : "ATS", "BEF", "CYP", "DEM", "EEK", "ESP", "EUR", "FIM", "FRF", "GRD", "IEP", "ITL", "LTL", "LUF", "LVL", "MTL", "NLG", "PTE", "SIT" et "SKK".
Un et seulement de texte1 ou texte2 doit être égal à "EUR".
=CONVERTIR_OOO(100;"ATS";"EUR") renvoie la valeur en Euro de 100 shillings autrichiens.
=CONVERTIR_OOO(100;"EUR";"DEM") convertit 100 Euros en marks allemands.
Référez-vous à la page de wiki CONVERTIR_OOO pour des détails complémentaires sur cette fonction.
Renvoie le cosinus de l'angle donné (en radians).
COS(nombre)
nombre est la valeur dont le cosinus est à calculer, l'angle en radians.
Pour renvoyer le cosinus d'un angle en degrés, utilisez la fonction RADIANS.
=COS(PI()*2) renvoie 1, le cosinus de 2*PI radians.
=COS(RADIANS(60)) renvoie 0,5, le cosinus de 60 degrés.
Renvoie le cosinus hyperbolique d'un nombre.
COSH(nombre)
Renvoie le cosinus hyperbolique de nombre.
=COSH(0) renvoie 1, le cosinus hyperbolique de 0.
Renvoie la cotangente de l'angle donné (en radians).
COT(nombre)
Renvoie la cotangente (trigonométrique) de nombre, l'angle est en radians.
Pour renvoyer la cotangente d'un angle en degrés, utilisez la fonction RADIANS.
La cotangente d'un angle est équivalente à 1 divisé par la tangente de cet angle.
=COT(PI()/4) renvoie 1, la cotangente de PI/4 radians.
=COT(RADIANS(45)) renvoie 1, la cotangente de 45 degrés.
Renvoie la cotangente hyperbolique d'un nombre donné (angle).
COTH(nombre)
Renvoie la cotangente hyperbolique de nombre.
=COTH(1) renvoie la cotangente hyperbolique de 1, approximativement 1,3130.
Renvoie la cosécante de l'angle donné (en radians). La cosécante d'un angle est équivalente à 1 divisé par le sinus de cet angle
CSC(nombre)
Renvoie la cosécante (trigonométrique) de nombre, l'angle en radians.
Pour renvoyer la cosécante d'un angle en degrés, utilisez la fonction RADIANS.
=CSC(PI()/4) renvoie approximativement 1,4142135624, l'inverse du sinus de PI/4 radians.
=CSC(RADIANS(30)) renvoie 2, la cosécante de 30 degrés.
Renvoie la cosécante hyperbolique d'un nombre.
CSCH(nombre)
Renvoie la cosécante hyperbolique de nombre.
=CSCH(1) renvoie approximativement 0,8509181282, la cosécante hyperbolique de 1.
Convertit les radians en degrés.
DEGRES(nombre)
nombre est l'angle en radians à convertir en degrés.
=DEGRES(PI()) renvoie 180 degrés.
Arrondit un nombre à l'entier immédiatement inférieur.
ENT(nombre)
Renvoie nombre à l'arrondi inférieur le plus proche du nombre entier.
Nombres négatifs arrondis au nombre entier inférieur.
=ENT(5,7) renvoie 5.
=ENT(-1,3) renvoie -2.
Convertit entre l'ancienne monnaie nationale européenne et vers et depuis l'euro.
EUROCONVERT(Valeur;"de_monnaie";"en_monnaie"[;précision_complète[;précision_triangulation]])
valeur est le montant de la monnaie à convertir.
de_monnaie et en_monnaie sont les unités monétaires à convertir de et en respectivement. Cela doit être du texte, l'abréviation officielle de la monnaie (par exemple "EUR"). Le taux de conversion (affiché en euro) a été fixé par la Commission Européenne.
Précision_complète est facultatif. Si omis ou faux, le résultat est arrondi en fonction des décimales de En monnaie. Si Précision_complète est vrai, le résultat n'est pas arrondi.
Précision_triangulation est facultatif. Si Précision_triangulation est donné et >=3, le résultat intermédiaire d'une conversion triangulaire (monnaie1,EUR,monnaie2) est arrondi à cette précision. Si Précision_triangulation est omis, le résultat intermédiaire n'est pas arrondi. De même, si la monnaie est "EUR", Précision_triangulation est utilisé comme si la triangulation était nécessaire et la conversion de EUR en EUR était appliquée.
=EUROCONVERT(100;"ATS";"EUR") convertit 100 shillings autrichiens en euros.
=EUROCONVERT(100;"EUR";"DEM") convertit 100 euros en marks allemands.
Renvoie e élevé à la puissance d'un nombre. La constante e a une valeur de 2,71828182845904 approximativement.
EXP(nombre)
nombre est la puissance à laquelle e doit être élevé.
=EXP(1) renvoie 2,71828182845904, la constante mathématique e à la précision de de Calc.
Renvoie la factorielle d'un entier non négatif.
FACT(nombre entier)
Renvoie Entier!, la factorielle de Entier, calculée comme 1*2*3*4* ... * entier.
Renvoie l'erreur « argument non valide » si l'argument est un entier négatif.
Renvoie l'erreur #VALEUR! si l'argument est supérieur à 170, car l'entier est trop grand (environ 7E+306).
=FACT(0) renvoie 1 par définition.
Si l'argument est un nombre non entier, il est converti en sa valeur entière plancher.
=FACT(3) renvoie 6.
=FACT(3,8) renvoie 6.
=FACT(0) renvoie 1.
Arrondit un nombre positif au nombre entier impair supérieur le plus proche, et un nombre négatif au nombre entier impair inférieur le plus proche.
IMPAIR(nombre)
Renvoie le nombre arrondi au plus proche nombre entier impair supérieur, éloigné de zéro.
=IMPAIR(1,2) renvoie 3.
=IMPAIR(1) renvoie 1.
=IMPAIR(0) renvoie 1.
=IMPAIR(-3,1) renvoie -5.
Renvoie le logarithme naturel à partir de la constante e d'un nombre. La constante e a une valeur approximative de 2,71828182845904.
LN(nombre)
nombre est la valeur dont vous souhaitez calculer le logarithme népérien.
=LN(3) renvoie le logarithme népérien de 3 (approximativement 1,0986).
=LN(EXP(321)) renvoie 321.
Renvoie le logarithme d'un nombre dans la base spécifiée.
LOG(nombre[;base])
nombre correspond à la valeur dont le logarithme est à calculer.
base (falcultatif) est la base pour le calcul du logarithme. Si omis, c'est la Base 10 qui est supposée.
=LOG(10;3) renvoie le logarithme de base 3 de 10 (approximativement 2,0959).
=LOG(7^4;7) renvoie 4.
Renvoie le logarithme en base 10 d'un nombre.
LOG10(nombre)
Renvoie le logarithme en base 10 du nombre.
=LOG10(5) renvoie le logarithme en base 10 de 5 (approximativement 0,69897).
Renvoie la différence après la division d'un nombre.
MOD(dividende;diviseur)
Pour les arguments de nombres entiers, cette fonction renvoie le dividende modulo le diviseur, c'est à dire le reste quand le dividende est divisé par le diviseur.
Cette fonction est implémentée comme dividende - diviseur * ENT(dividende/diviseur) , et cette formule donne le résultat si l'argument n'est pas un nombre entier.
=MOD(22;3) renvoie 1, le reste quand 22 est divisé par 3.
=MOD(11,25;2,5) renvoie 1,25.
Renvoie la factorielle de la somme des arguments divisée par le produit des factorielles des arguments.
MULTINOMIALE(nombre1[;nombre2[;...;[nombre255]]]complexe1[;complexe2[;...;[complexe255]]])
=MULTINOMIALE(F11:H11) renvoie 1260, si F11 à H11 contiennent les valeurs 2, 3 et 4. Cela correspond à la formule =(2+3+4)!/(2!*3!*4!)
Arrondit un nombre positif au nombre entier pair supérieur le plus proche et un nombre négatif au nombre entier pair inférieur le plus proche.
PAIR(nombre)
Renvoie le nombre arrondi au plus proche nombre entier pair supérieur, éloigné de zéro.
=PAIR(2,3) renvoie 4.
=PAIR(2) renvoie 2.
=PAIR(0) renvoie 0.
=PAIR(-0,5) renvoie -2.
Renvoie le plus grand diviseur commun de plusieurs nombres entiers.
Le plus grand diviseur commun est l'entier positif le plus grand permettant de diviser sans reste chacun des entiers donnés.
PGCD(entier1[;entier2[;...;[entier255]]])
=PGCD(16;32;24) donne 8 comme résultat, parce que 8 est le plus grand nombre qui peut diviser 16, 24 et 32 sans reste.
=PGCD(B1:B3) où les cellules B1, B2, B3 contiennent 9, 12, 9 renvoie 3.
Renvoie le plus grand diviseur commun d'une liste de nombres.
PGCD_EXCEL2003(nombre1[;nombre2[;...;[nombre255]]]complexe1[;complexe2[;...;[complexe255]]])
=PGCD_EXCEL2003(5;15;25) renvoie 5.
Renvoie 3,14159265358979, la valeur de la constante mathématique PI à 14 décimales.
PI ()
=PI() renvoie 3,14159265358979.
Renvoie le plus petit multiple commun d'un ou de plusieurs nombres entiers.
PPCM(entier1[;entier2[;...;[entier255]]])
Si vous entrez les chiffres 512 ; 1024 et 2000 en tant qu'entiers 1 ; 2 et 3, alors 128000 sera retourné.
Le résultat est le plus petit multiple commun d'une liste de nombres.
PPCM_EXCEL2003(nombre1[;nombre2[;...;[nombre255]]]complexe1[;complexe2[;...;[complexe255]]])
=PPCM_EXCEL2003(5;15;25) revoie 75.
Donne le produit de la multiplication de tous les nombres donnés comme arguments.
PRODUIT(nombre1[;nombre2[;...;[nombre255]]]complexe1[;complexe2[;...;[complexe255]]])
=PRODUIT(2;3;4) renvoie 24.
Renvoie un nombre élevé à un autre nombre.
PUISSANCE (base; exposant)
Renvoie la base élevée à la puissance de exposant.
Le même résultat peut être obtenu en utilisant l'opérateur d'exponentiation ^ : Base^Exposant
=PUISSANCE(0,0) renvoie 1 ; =PUISSANCE(0,X) signale l'erreur #NUM ! lorsque l'exposant X est négatif.
=PUISSANCE(B,X) peut ou non signaler une erreur #NUM ! lorsque B est négatif et X n'est pas un entier.
=PUISSANCE(4;3) renvoie 64, soit 4 à la puissance 3.
=4^3 renvoie aussi 4 à la puissance 3.
=PUISSANCE(2;-3) renvoie 0,125.
=PUISSANCE(-2;1/3) renvoie -1,25992104989487.
=PUISSANCE(-2;2/3) renvoie l'erreur #NUM !.
Renvoie la partie entière d'une division.
QUOTIENT(numérateur; dénominateur)
Renvoie la partie du nombre entier du numérateur divisé par le dénominateur.
QUOTIENT est équivalent à ENT(numérateur/dénominateur) pour un numérateur et un dénominateur du même signe, excepté qu'il peut renvoyer des erreurs avec des codes d'erreur différents. Plus généralement, il équivaut à ENT(numérateur/dénominateur/SIGN(numétateur/dénominateur))*SIGN(numérateur/dénominateur).
=QUOTIENT(11;3) renvoie 3. Le reste 2 est perdu.
Renvoie la racine carrée positive d'un nombre.
RACINE(nombre)
Renvoie la racine carrée positive de nombre.
nombre doit être positif.
=RACINE(16) renvoie 4.
=RACINE(-16) renvoie une erreur argument invalide.
Renvoie la racine carrée d'un nombre*PI.
RACINE.PI(nombre)
Renvoie la racine carrée positive de (PI multiplié par nombre).
C'est l'équivalent de RACINE(PI()*nombre).
=RACINE.PI(2) renvoie la racine carrée de (2PI), approximativement 2,506628.
Convertit les degrés en radians.
RADIANS(nombre)
nombre est l'angle en degrés à convertir en radians.
=RADIANS(90) renvoie 1,5707963267949, qui est PI/2 à la précision de Calc.
Renvoie la sécante d'un angle donné (en radians). La sécante d'un angle est équivalente à 1 divisé par le cosinus de cet angle
SEC(nombre)
Renvoie la sécante (trigonométrique) de nombre, l'angle en radians.
Pour renvoyer la sécante d'un angle en degrés, utilisez la fonction RADIANS.
=SEC(PI()/4) renvoie approximativement 1.4142135624, l'inverse du cosinus de PI/4 radians.
=SEC(RADIANS(60)) renvoie 2, la sécante de 60 degrés.
Renvoie la sécante hyperbolique d'un nombre.
SECH(nombre)
Renvoie la sécante hyperbolique de nombre.
=SECH(0) renvoie 1, la sécante hyperbolique de 0.
Renvoie le signe d'un nombre. Renvoie 1 si le nombre est positif, -1 si négatif et 0 si zéro.
SIGNE(nombre)
nombre est le nombre dont le signe doit être déterminé.
=SIGNE(3,4) renvoie 1.
=SIGNE(-4,5) renvoie -1.
Renvoie le sinus du nombre donné (en radians).
SIN(nombre)
Renvoie le sinus (trigonométrique) de nombre, l'angle est en radians.
Pour renvoyer le sinus d'un angle en degrés, utilisez la fonction RADIANS.
=SIN(PI()/2) renvoie 1, le sinus de PI/2 radians.
=SIN(RADIANS(30)) renvoie 0,5, le sinus de 30 degrés.
Renvoie le sinus hyperbolique d'un nombre.
SINH(nombre)
Renvoie le sinus hyperbolique de Nombre.
=SINH(0) renvoie 0, le sinus hyperbolique de 0.
Calcule la somme des carrés d'un ensemble de nombres.
SOMME.CARRES(nombre1[;nombre2[;...;[nombre255]]]complexe1[;complexe2[;...;[complexe255]]])
Si vous saisissez les chiffres 2 ; 3 et 4 dans Nombre 1 ; 2 et 3 arguments, 29 est retourné comme résultat.
Additionne les premiers termes d'une série de puissances
SOMME.SERIES(x;n;m;c) = c1xn + c2xn+m + c3xn+2m + ... + cixn + (i-1)m.
SOMME.SERIES(x;n;m;coefficients)
x est la valeur de saisie de la série de puissances.
n est la puissance initiale
m est l'incrément pour augmenter n
coefficients est une série de coefficients. Pour chaque coefficient, la somme des séries est étendue d'une section.
=SOMME.SERIES(A1;0; 1; {1; 2; 3}) calcul la valeur de 1+2x+3x2, où x est la valeur de la cellule A1. Si A1 contient 1, la formule renvoie 6 ; si A1 contient 2, la formule renvoie 17 ; si A1 contient 3, la formule renvoie 34 et ainsi de suite.
Référez-vous à la page de wiki SOMME.SERIES pour des détails complémentaires sur cette fonction.
Calcule les sous-totaux. Si une plage donnée contient déjà des sous-totaux, ceux-ci ne sont pas utilisés pour des calculs ultérieurs. Pour que le calcul ne porte que sur les enregistrements filtrés, associez cette fonction aux AutoFiltres.
SOUS.TOTAL(fonction;plage)
fonction est un nombre qui représente l'une des fonctions suivantes :
| Index des fonctions (inclut les valeurs masquées) | Index des fonctions (ignore les valeurs masquées) | Fonctions | 
|---|---|---|
| 1 | 101 | MOYENNE | 
| 2 | 102 | NB | 
| 3 | 103 | NBVAL | 
| 4 | 104 | MAX | 
| 5 | 105 | MIN | 
| 6 | 106 | PRODUIT | 
| 7 | 107 | ECARTYPE | 
| 8 | 108 | ECARTYPEP | 
| 9 | 109 | SUM | 
| 10 | 110 | VAR | 
| 11 | 111 | VARP | 
Utilisez les nombres 1-11 pour inclure manuellement les lignes masquées ou 101-111 pour les exclure ; les cellules filtrées sont toujours exclues.
plage correspond à la plage dont les cellules sont incluses.
Vous avez une table dans la plage de cellules A1:B6 contenant une nomenclature pour 10 étudiants.
| A | B | |
|---|---|---|
| 1 | ÉLÉMENT | QUANTITÉ | 
| 2 | Stylo | 10 | 
| 3 | Crayon | 10 | 
| 4 | Bloc-notes | 10 | 
| 5 | Gomme | 10 | 
| 6 | Taille-crayons | 10 | 
Disons qu'une ligne est masquée manuellement, alors la première formule affiche la somme des 5 chiffres filtrés ; la seconde, uniquement la somme des 4 chiffres affichés.
=SOUS.TOTAL(9;B2:B6) renvoie 50.
=SOUS.TOTAL(109;B2:B6) renvoie 40.
Renvoie la tangente de l'angle donné (en radians).
TAN(nombre)
Renvoie la tangente (trigonométrique) de Nombre, l'angle est en radians.
Pour renvoyer la tangente d'un angle en degrés, utilisez la fonction RADIANS.
=TAN(PI()/4) renvoie 1, la tangente de PI/4 radians.
=TAN(RADIANS(45)) renvoie 1, la tangente de 45 degrés.
Renvoie la tangente hyperbolique d'un nombre.
TANH(nombre)
Renvoie la tangente hyperbolique de Nombre.
=TANH(0) renvoie 0, la tangente hyperbolique de 0.