TITLE: i think - or thinking is visible
NAME: Bernd Voigt
COUNTRY: Germany
EMAIL: b.voigt@web.de
WEBPAGE: http://home.t-online.de/home/b.voigt/
TOPIC: inner working
COPYRIGHT: I SUBMIT TO THE STANDARD RAYTRACING COMPETITION COPYRIGHT.
MPGFILE: think.mpg
ZIPFILE: 
RENDERER USED: 
    POV-Ray 3.02 by W98

TOOLS USED: 
    a quick cam for the background
    Corel Photopaint and my UMAX Astra for the bitmaps
    MainActor for the mpeg-file

CREATION TIME: 
    I work one week on this theme.
    The render time is 35 min.

VIEWING RECOMMENDATION:      
    The best view is full color, 24 frames per second and the loop mode by the player. 
    Or a gif file with loop block. (See on my gallery.) 

ANIMATION DESCRIPTION: 
    Inner Working - i mean, one can see it ;-)


DESCRIPTION OF HOW THIS ANIMATION WAS CREATED: 

The pov file contains only simple objects. The butterfly was created 
with a scanned bitmap as coloured wing.

#declare wingblue=
union {
    object { UnitBox                            //left wing container box
        scale <8, 0.001, 8>
        pigment {
            image_map {
                gif "wingblue.gif"              //calls the bitmap for colouring
                once
                interpolate 2
                transmit 0 1                    //full transmit Index0
            }
            translate -0.5                      //center the bitmap
            scale 16
            rotate <90, -90, 0>
        }
        translate z*-8                          //
        rotate x*20                             //to tilt the wing
        rotate x*40*sin(10*clock*2*pi)          //makes to flutter
    }
    object { UnitBox                            //right wing container box                         
        scale <8, 0.001, 8>
        pigment {
            image_map {
                gif "wingblue.gif"              //calls the bitmap for colouring
                once
                interpolate 2
                transmit 0 1                    //full transmit Index                    
            }
            translate -0.5                      //center the bitmap
            scale 16
            rotate <-90, 90, 0>
        }
        translate z*8                          //                           
        rotate x*-20                           //to tilt the wing                            
        rotate x*-40*sin(10*clock*2*pi)        //makes to flutter         
    }
}

The call of object wingblue contains many combinations of translates and rotations 
with the sinus function. You can test various combinations. It is easy.
Here is a example with a primitive model. 
It is not the original file was create this animation.

begin of file butterfly.pov ---------------------------------------------------------------

// Persistence Of Vision Raytracer version 3.0 sample file.
// a raytracing experiment by b.voigt
// a butterfly (primitive model) in motion
// 6/2000

#include "colors.inc"
#include "shapes.inc"

camera {
  location  <0, 10, -150>
  look_at   0
  angle 52
}

light_source { <100, 200, -300> color White }
background {color Grey}

#declare butterfly=
union {
    sphere {                                  //head
        <-5, 0, 0> 1
        pigment {color Brown}
    }
    cylinder {                                //body
        <-4, 0, 0> <5, 0, 0> 1
        pigment {color Brown}
    }
    sphere {                                  //left wing
        <0, 0, -8> 8
        scale <1, 0.1, 1>
        rotate x*20                           //to tilt the wing
        rotate x*50*sin(10*clock*2*pi)        //makes to flutter  
        pigment {Green}
    }
    sphere {                                  //right wing
        <0, 0, 8> 8
        scale <1, 0.1, 1>
        rotate x*-20                          //to tilt the wing
        rotate x*-50*sin(10*clock*2*pi)       //makes to flutter  
        pigment {color Green}
    }
}

object {                                      //calls the define object
    butterfly
    rotate x*10*sin(5*clock*2*pi)             //makes giddy
    translate x*10*sin(clock*2*pi)            //makes a anomalous trajectory
    translate y*10*sin(clock*2*pi)            //makes a slight up and down
    translate x*30                            //move the object to the circular path
    rotate 360*clock*y                        //moves the object in the circular path one round
}

end of file ------------------------------------------------------------------------------

The Pov-Ray ini file should have follow data.

begin of file butterfly.ini --------------------------------------------------------------

Width=320
Height=240

Antialias_Threshold=0.3
Antialias_Depth=3

Input_File_Name=butterfly.pov                 //the name the Pov-Ray (input) file
Output_File_Name=bfly.tga                     //output file names in the same directory
Initial_Frame=1
Final_Frame=80                                //speciefy the quantity of frames
Initial_Clock=0
Final_Clock=1

Pause_when_Done=off

end of file ------------------------------------------------------------------------------