Import('env')
Import('debugBuild')
protobuf_env = env.Clone(NINJA_GENSOURCE_INDEPENDENT=True)

protobuf_env.InjectThirdParty(libraries=['zlib'])

protobuf_env.Append(CPPDEFINES=[
    'HAVE_CONFIG_H',
    ('HAVE_ZLIB', '1'),
    ('PIC', '1'),
], )

if protobuf_env.ToolchainIs('gcc', 'clang'):
    protobuf_env.Append(
        CPPDEFINES=[
            ('HAVE_PTHREAD', '1'),
        ],
        CCFLAGS=[
            '-Wno-sign-compare',
            '-Wno-overloaded-virtual',
        ],
    )
    if debugBuild:
        protobuf_env.Append(CCFLAGS=['-Wno-error'])

if protobuf_env.ToolchainIs('gcc'):
    protobuf_env.Append(
        CPPDEFINES=[],
        CCFLAGS=[
            '-Wno-stringop-overflow',
        ],
    )

if protobuf_env.ToolchainIs('msvc'):
    protobuf_env.Append(
        CCFLAGS=[
            '/wd4018',  # signed/unsigned mismatch
            '/wd4065',  # switch statement contains 'default' but no 'case' labels
            '/wd4146',  # unary minus operator applied to unsigned type, result still unsigned
        ],
        CPPDEFINES=[
            '_SILENCE_CXX17_ITERATOR_BASE_CLASS_DEPRECATION_WARNING',
        ],
    )

protobuf_root = protobuf_env.Dir(".").srcnode()
protobuf_platform = protobuf_root.Dir("platform/${TARGET_OS}_${TARGET_ARCH}")
protobuf_env.Append(CPPPATH=[
    protobuf_root.Dir("dist"),
    protobuf_root.Dir("dist/src"),
], )

# Passing this up to the main env
env['PROTOC_DESCRIPTOR_PROTO'] = protobuf_env.File(
    "dist/src/google/protobuf/descriptor.proto").abspath

protobuf_env.Library(
    target='protobuf',
    source=[
        "dist/src/google/protobuf/any_lite.cc",
        "dist/src/google/protobuf/arena.cc",
        "dist/src/google/protobuf/arenastring.cc",
        "dist/src/google/protobuf/extension_set.cc",
        "dist/src/google/protobuf/generated_enum_util.cc",
        "dist/src/google/protobuf/generated_message_table_driven_lite.cc",
        "dist/src/google/protobuf/generated_message_tctable_lite.cc",
        "dist/src/google/protobuf/generated_message_util.cc",
        "dist/src/google/protobuf/implicit_weak_message.cc",
        "dist/src/google/protobuf/inlined_string_field.cc",
        "dist/src/google/protobuf/io/coded_stream.cc",
        "dist/src/google/protobuf/io/io_win32.cc",
        "dist/src/google/protobuf/io/strtod.cc",
        "dist/src/google/protobuf/io/zero_copy_stream.cc",
        "dist/src/google/protobuf/io/zero_copy_stream_impl.cc",
        "dist/src/google/protobuf/io/zero_copy_stream_impl_lite.cc",
        "dist/src/google/protobuf/map.cc",
        "dist/src/google/protobuf/message_lite.cc",
        "dist/src/google/protobuf/parse_context.cc",
        "dist/src/google/protobuf/repeated_field.cc",
        "dist/src/google/protobuf/repeated_ptr_field.cc",
        "dist/src/google/protobuf/stubs/bytestream.cc",
        "dist/src/google/protobuf/stubs/common.cc",
        "dist/src/google/protobuf/stubs/int128.cc",
        "dist/src/google/protobuf/stubs/status.cc",
        "dist/src/google/protobuf/stubs/statusor.cc",
        "dist/src/google/protobuf/stubs/stringpiece.cc",
        "dist/src/google/protobuf/stubs/stringprintf.cc",
        "dist/src/google/protobuf/stubs/structurally_valid.cc",
        "dist/src/google/protobuf/stubs/strutil.cc",
        "dist/src/google/protobuf/stubs/time.cc",
        "dist/src/google/protobuf/wire_format_lite.cc",
        "dist/src/google/protobuf/any.cc",
        "dist/src/google/protobuf/any.pb.cc",
        "dist/src/google/protobuf/api.pb.cc",
        "dist/src/google/protobuf/compiler/importer.cc",
        "dist/src/google/protobuf/compiler/parser.cc",
        "dist/src/google/protobuf/descriptor.cc",
        "dist/src/google/protobuf/descriptor.pb.cc",
        "dist/src/google/protobuf/descriptor_database.cc",
        "dist/src/google/protobuf/duration.pb.cc",
        "dist/src/google/protobuf/dynamic_message.cc",
        "dist/src/google/protobuf/empty.pb.cc",
        "dist/src/google/protobuf/extension_set_heavy.cc",
        "dist/src/google/protobuf/field_mask.pb.cc",
        "dist/src/google/protobuf/generated_message_bases.cc",
        "dist/src/google/protobuf/generated_message_reflection.cc",
        "dist/src/google/protobuf/generated_message_table_driven.cc",
        "dist/src/google/protobuf/generated_message_tctable_full.cc",
        "dist/src/google/protobuf/io/gzip_stream.cc",
        "dist/src/google/protobuf/io/printer.cc",
        "dist/src/google/protobuf/io/tokenizer.cc",
        "dist/src/google/protobuf/map_field.cc",
        "dist/src/google/protobuf/message.cc",
        "dist/src/google/protobuf/reflection_ops.cc",
        "dist/src/google/protobuf/service.cc",
        "dist/src/google/protobuf/source_context.pb.cc",
        "dist/src/google/protobuf/struct.pb.cc",
        "dist/src/google/protobuf/stubs/substitute.cc",
        "dist/src/google/protobuf/text_format.cc",
        "dist/src/google/protobuf/timestamp.pb.cc",
        "dist/src/google/protobuf/type.pb.cc",
        "dist/src/google/protobuf/unknown_field_set.cc",
        "dist/src/google/protobuf/util/delimited_message_util.cc",
        "dist/src/google/protobuf/util/field_comparator.cc",
        "dist/src/google/protobuf/util/field_mask_util.cc",
        "dist/src/google/protobuf/util/internal/datapiece.cc",
        "dist/src/google/protobuf/util/internal/default_value_objectwriter.cc",
        "dist/src/google/protobuf/util/internal/error_listener.cc",
        "dist/src/google/protobuf/util/internal/field_mask_utility.cc",
        "dist/src/google/protobuf/util/internal/json_escaping.cc",
        "dist/src/google/protobuf/util/internal/json_objectwriter.cc",
        "dist/src/google/protobuf/util/internal/json_stream_parser.cc",
        "dist/src/google/protobuf/util/internal/object_writer.cc",
        "dist/src/google/protobuf/util/internal/proto_writer.cc",
        "dist/src/google/protobuf/util/internal/protostream_objectsource.cc",
        "dist/src/google/protobuf/util/internal/protostream_objectwriter.cc",
        "dist/src/google/protobuf/util/internal/type_info.cc",
        "dist/src/google/protobuf/util/internal/utility.cc",
        "dist/src/google/protobuf/util/json_util.cc",
        "dist/src/google/protobuf/util/message_differencer.cc",
        "dist/src/google/protobuf/util/time_util.cc",
        "dist/src/google/protobuf/util/type_resolver_util.cc",
        "dist/src/google/protobuf/wire_format.cc",
        "dist/src/google/protobuf/wrappers.pb.cc",
    ],
    LIBDEPS=[
        '$BUILD_DIR/third_party/shim_zlib',
    ],
)

protobuf_env.Library(
    target='protoc',
    source=[
        "dist/src/google/protobuf/compiler/code_generator.cc",
        "dist/src/google/protobuf/compiler/command_line_interface.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_enum.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_enum_field.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_extension.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_field.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_file.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_generator.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_helpers.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_map_field.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_message.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_message_field.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_padding_optimizer.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_parse_function_generator.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_primitive_field.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_service.cc",
        "dist/src/google/protobuf/compiler/cpp/cpp_string_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_doc_comment.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_enum.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_enum_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_field_base.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_generator.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_helpers.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_map_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_message.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_message_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_primitive_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_reflection_class.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_repeated_enum_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_repeated_message_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_repeated_primitive_field.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_source_generator_base.cc",
        "dist/src/google/protobuf/compiler/csharp/csharp_wrapper_field.cc",
        "dist/src/google/protobuf/compiler/java/java_context.cc",
        "dist/src/google/protobuf/compiler/java/java_doc_comment.cc",
        "dist/src/google/protobuf/compiler/java/java_enum.cc",
        "dist/src/google/protobuf/compiler/java/java_enum_field.cc",
        "dist/src/google/protobuf/compiler/java/java_enum_field_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_enum_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_extension.cc",
        "dist/src/google/protobuf/compiler/java/java_extension_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_field.cc",
        "dist/src/google/protobuf/compiler/java/java_file.cc",
        "dist/src/google/protobuf/compiler/java/java_generator.cc",
        "dist/src/google/protobuf/compiler/java/java_generator_factory.cc",
        "dist/src/google/protobuf/compiler/java/java_helpers.cc",
        "dist/src/google/protobuf/compiler/java/java_kotlin_generator.cc",
        "dist/src/google/protobuf/compiler/java/java_map_field.cc",
        "dist/src/google/protobuf/compiler/java/java_map_field_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_message.cc",
        "dist/src/google/protobuf/compiler/java/java_message_builder.cc",
        "dist/src/google/protobuf/compiler/java/java_message_builder_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_message_field.cc",
        "dist/src/google/protobuf/compiler/java/java_message_field_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_message_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_name_resolver.cc",
        "dist/src/google/protobuf/compiler/java/java_primitive_field.cc",
        "dist/src/google/protobuf/compiler/java/java_primitive_field_lite.cc",
        "dist/src/google/protobuf/compiler/java/java_service.cc",
        "dist/src/google/protobuf/compiler/java/java_shared_code_generator.cc",
        "dist/src/google/protobuf/compiler/java/java_string_field.cc",
        "dist/src/google/protobuf/compiler/java/java_string_field_lite.cc",
        "dist/src/google/protobuf/compiler/js/js_generator.cc",
        "dist/src/google/protobuf/compiler/js/well_known_types_embed.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_enum.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_enum_field.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_extension.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_field.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_file.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_generator.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_helpers.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_map_field.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_message.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_message_field.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_oneof.cc",
        "dist/src/google/protobuf/compiler/objectivec/objectivec_primitive_field.cc",
        "dist/src/google/protobuf/compiler/php/php_generator.cc",
        "dist/src/google/protobuf/compiler/plugin.cc",
        "dist/src/google/protobuf/compiler/plugin.pb.cc",
        "dist/src/google/protobuf/compiler/python/python_generator.cc",
        "dist/src/google/protobuf/compiler/ruby/ruby_generator.cc",
        "dist/src/google/protobuf/compiler/subprocess.cc",
        "dist/src/google/protobuf/compiler/zip_writer.cc",
    ],
    LIBDEPS=[
        'protobuf',
    ],
)

protobuf_compiler = protobuf_env.Program(
    target='protobuf_compiler',
    source=['dist/src/google/protobuf/compiler/main.cc'],
    LIBDEPS=[
        'protobuf',
        'protoc',
    ],
    AIB_COMPONENT='protobuf',
)

installed = env.GetAutoInstalledFiles(protobuf_compiler[0])
if installed:
    setattr(installed[0].attributes, 'AIB_NO_ARCHIVE', True)
